feat: ImGui docking Editor + 显示链/帧同步/输入语义重构
- App/editor: Hierarchy/Inspector/Viewport/Stats 四面板 + DockBuilder 默认布局，main.cpp 瘦身为场景搭建与生命周期 - 显示链: Tonemap→PresentTarget 经 ImGui::Image 呈现（零色偏），backbuffer 仅承载 ImGui；Direct/Viewport 双显示模式 + 面板分辨率上报 - 帧首同步 BeginFrameSync: resize/vsync/尺寸/模式意图统一帧首落定（修描述符悬垂）；修复 vsync 意图未落 swapchain 导致的每帧重建交换链 - 输入: Editor 每帧判定键盘/鼠标归属（打字让位、Viewport hover/focus 放行、Fullscreen 全放行） - 材质: roughness 独立槽位 + 非 glTF 金属/粗糙贴图映射；透明队列 depthWrite=FALSE + translucent 独立 shader + scratch 清帧 - FBX: 非蒙皮网格烘焙节点链全局变换（Z-up 旋转/单位换算落顶点） - Hierarchy 行 ImGui ID 以 UUID 作用域（重名不冲突、改名不丢选中）
This commit is contained in:
+24
-2
@@ -3,17 +3,39 @@
|
||||
// Shadow pass vertex：光源视角写深度。
|
||||
// GPUDriven：模型矩阵经 gl_InstanceIndex 从实例缓冲取（与 Forward
|
||||
// 共用同一份数据），push 只带 lightVP（全 pass 一次）。
|
||||
// 骨骼蒙皮与 Forward 同一套数据（binding 3/4），阴影与主体形变一致。
|
||||
|
||||
layout(location = 0) in vec3 inPosition;
|
||||
layout(location = 4) in uvec4 inBoneIds; // 骨骼槽（palette 下标）
|
||||
layout(location = 5) in vec4 inWeights; // 蒙皮权重（无骨骼顶点 = (1,0,0,0)）
|
||||
|
||||
layout(std430, set = 0, binding = 1) readonly buffer ObjectBuffer {
|
||||
mat4 models[];
|
||||
} objects;
|
||||
|
||||
// 骨骼蒙皮：与 simple_shader.vert 同布局（Set0 binding 3/4）
|
||||
layout(std430, set = 0, binding = 3) readonly buffer SkinOffsetBuffer {
|
||||
uint skinBases[];
|
||||
} skinOffsets;
|
||||
|
||||
layout(std430, set = 0, binding = 4) readonly buffer SkinPaletteBuffer {
|
||||
mat4 bones[];
|
||||
} skinPalettes;
|
||||
|
||||
layout(push_constant) uniform PushConstants {
|
||||
mat4 lightVP;
|
||||
} pc;
|
||||
|
||||
void main() {
|
||||
gl_Position = pc.lightVP * objects.models[gl_InstanceIndex] * vec4(inPosition, 1.0);
|
||||
mat4 SkinMatrix() {
|
||||
uint base = skinOffsets.skinBases[gl_InstanceIndex];
|
||||
return skinPalettes.bones[base + inBoneIds.x] * inWeights.x +
|
||||
skinPalettes.bones[base + inBoneIds.y] * inWeights.y +
|
||||
skinPalettes.bones[base + inBoneIds.z] * inWeights.z +
|
||||
skinPalettes.bones[base + inBoneIds.w] * inWeights.w;
|
||||
}
|
||||
|
||||
void main() {
|
||||
mat4 skin = SkinMatrix();
|
||||
vec3 skinnedPos = (skin * vec4(inPosition, 1.0)).xyz;
|
||||
gl_Position = pc.lightVP * objects.models[gl_InstanceIndex] * vec4(skinnedPos, 1.0);
|
||||
}
|
||||
|
||||
@@ -40,8 +40,9 @@ layout(set = 1, binding = 1) uniform sampler2D normalMap;
|
||||
layout(set = 1, binding = 2) uniform sampler2D metallicRoughnessMap; // G=粗糙度 B=金属度
|
||||
layout(set = 1, binding = 3) uniform sampler2D emissiveMap;
|
||||
layout(set = 1, binding = 4) uniform sampler2D aoMap; // 环境光遮蔽（R 通道）
|
||||
layout(set = 1, binding = 5) uniform MaterialParams {
|
||||
vec4 factors; // x = metallic 因子，y = roughness 因子
|
||||
layout(set = 1, binding = 5) uniform sampler2D roughnessMap; // 独立粗糙度图（R 通道，specular 工作流）
|
||||
layout(set = 1, binding = 6) uniform MaterialParams {
|
||||
vec4 factors; // x = metallic 因子，y = roughness 因子，z = 独立粗糙度图开关
|
||||
} matParams;
|
||||
|
||||
// CSM 阴影（sampler2DShadow：单次采样 = 硬件 2×2 深度比较 PCF）
|
||||
@@ -134,9 +135,14 @@ vec3 FresnelSchlickRoughness(float cosTheta, vec3 F0, float roughness) {
|
||||
}
|
||||
|
||||
void main() {
|
||||
vec3 albedo = texture(albedoMap, fragUV).rgb;
|
||||
vec4 albedoTex = texture(albedoMap, fragUV);
|
||||
vec3 albedo = albedoTex.rgb;
|
||||
vec4 mr = texture(metallicRoughnessMap, fragUV);
|
||||
float roughness = clamp(mr.g * matParams.factors.y, 0.045, 1.0);
|
||||
// 粗糙度源按 factors.z 切换：glTF 合图工作流读 MR.g；
|
||||
// FBX/OBJ specular 工作流（z=1）换用独立粗糙度图 R 通道
|
||||
float roughness = clamp(mix(mr.g, texture(roughnessMap, fragUV).r,
|
||||
matParams.factors.z) * matParams.factors.y,
|
||||
0.045, 1.0);
|
||||
float metallic = clamp(mr.b * matParams.factors.x, 0.0, 1.0);
|
||||
vec3 emissive = texture(emissiveMap, fragUV).rgb;
|
||||
|
||||
@@ -217,6 +223,8 @@ void main() {
|
||||
vec3 ambient = (diffuse + specular) * ubo.ambientColor.rgb
|
||||
* mix(0.4, 1.0, shade0); // 阴影区环境同步衰减（简化遮蔽）
|
||||
|
||||
outColor = vec4(ambient + Lo + emissive, 1.0);
|
||||
// alpha = albedo 贴图覆盖率（glTF alphaMode=BLEND 混合源）；
|
||||
// 不透明资产贴图 a=1 行为不变。预乘在 tonemap 段完成。
|
||||
outColor = vec4(ambient + Lo + emissive, albedoTex.a);
|
||||
outVelocity = fragVelocity;
|
||||
}
|
||||
|
||||
@@ -13,6 +13,8 @@ layout(location = 0) in vec3 inPosition;
|
||||
layout(location = 1) in vec3 inNormal;
|
||||
layout(location = 2) in vec2 inUV;
|
||||
layout(location = 3) in vec3 inTangent;
|
||||
layout(location = 4) in uvec4 inBoneIds; // 骨骼槽（palette 下标，非全局节点号）
|
||||
layout(location = 5) in vec4 inWeights; // 蒙皮权重（无骨骼顶点 = (1,0,0,0)）
|
||||
|
||||
layout(location = 0) out vec2 fragUV;
|
||||
layout(location = 1) out vec3 fragNormal;
|
||||
@@ -33,6 +35,15 @@ layout(std430, set = 0, binding = 2) readonly buffer PrevObjectBuffer {
|
||||
mat4 prevModels[];
|
||||
} prevObjects;
|
||||
|
||||
// 骨骼蒙皮：每实例一个 palette 基址（与 models 平行），骨骼矩阵全局扁平
|
||||
layout(std430, set = 0, binding = 3) readonly buffer SkinOffsetBuffer {
|
||||
uint skinBases[]; // 实例 → palette 基址
|
||||
} skinOffsets;
|
||||
|
||||
layout(std430, set = 0, binding = 4) readonly buffer SkinPaletteBuffer {
|
||||
mat4 bones[]; // 全局 palette（槽 0 = identity，静态模型直通）
|
||||
} skinPalettes;
|
||||
|
||||
layout(set = 0, binding = 0) uniform UniformBufferObject {
|
||||
mat4 view;
|
||||
mat4 proj;
|
||||
@@ -46,16 +57,28 @@ layout(set = 0, binding = 0) uniform UniformBufferObject {
|
||||
vec4 cameraPos;
|
||||
} ubo;
|
||||
|
||||
// 4 权重混合的蒙皮矩阵。无骨骼顶点 weights=(1,0,0,0)+ids=0 → identity。
|
||||
mat4 SkinMatrix() {
|
||||
uint base = skinOffsets.skinBases[gl_InstanceIndex];
|
||||
return skinPalettes.bones[base + inBoneIds.x] * inWeights.x +
|
||||
skinPalettes.bones[base + inBoneIds.y] * inWeights.y +
|
||||
skinPalettes.bones[base + inBoneIds.z] * inWeights.z +
|
||||
skinPalettes.bones[base + inBoneIds.w] * inWeights.w;
|
||||
}
|
||||
|
||||
void main() {
|
||||
mat4 model = objects.models[gl_InstanceIndex];
|
||||
mat4 skin = SkinMatrix();
|
||||
|
||||
vec4 worldPos = model * vec4(inPosition, 1.0);
|
||||
vec3 skinnedPos = (skin * vec4(inPosition, 1.0)).xyz;
|
||||
vec4 worldPos = model * vec4(skinnedPos, 1.0);
|
||||
gl_Position = ubo.proj * ubo.view * worldPos;
|
||||
|
||||
// ---- TAA velocity：当前帧与上一帧的 clip 空间位置差（UV 空间）----
|
||||
// 抖动只进光栅化 gl_Position，不进 velocity（否则抖动本身被当成运动）
|
||||
// v1：蒙皮形变不进 velocity（prev 用同一蒙皮姿态），边缘 ghosting 接受
|
||||
vec4 currClip = ubo.projNoJitter * ubo.view * worldPos;
|
||||
vec4 prevWorldPos = prevObjects.prevModels[gl_InstanceIndex] * vec4(inPosition, 1.0);
|
||||
vec4 prevWorldPos = prevObjects.prevModels[gl_InstanceIndex] * vec4(skinnedPos, 1.0);
|
||||
vec4 prevClip = ubo.prevProj * ubo.prevView * prevWorldPos;
|
||||
fragVelocity = (currClip.xy / currClip.w - prevClip.xy / prevClip.w) * 0.5;
|
||||
|
||||
@@ -64,9 +87,10 @@ void main() {
|
||||
fragViewDepth = -(ubo.view * worldPos).z;
|
||||
|
||||
mat3 normalMatrix = mat3(transpose(inverse(model)));
|
||||
fragNormal = normalize(normalMatrix * inNormal);
|
||||
// 法线先过蒙皮旋转（形变方向），再过模型逆变换
|
||||
fragNormal = normalize(normalMatrix * (mat3(skin) * inNormal));
|
||||
// 切线随模型变换（法线贴图 TBN；无切线数据保持零，frag 侧退回几何法线）
|
||||
fragTangent = normalize(mat3(model) * inTangent);
|
||||
fragTangent = normalize(mat3(model) * (mat3(skin) * inTangent));
|
||||
// 零向量 normalize 产生 NaN，这里直接透传零，frag 判长度
|
||||
fragTangent = dot(inTangent, inTangent) > 0.0 ? fragTangent : vec3(0.0);
|
||||
|
||||
|
||||
@@ -0,0 +1,238 @@
|
||||
#version 450
|
||||
|
||||
const int MAX_LIGHTS = 4;
|
||||
const float PI = 3.14159265359;
|
||||
const int kCascadeRes = 1024; // CSM 级联图边长（与引擎 SceneTypes.h 同步）
|
||||
|
||||
struct Light {
|
||||
vec4 color; // rgb = 颜色，a = 强度
|
||||
vec4 direction; // 方向光：xyz = 方向（已归一）
|
||||
vec4 position; // 点光：xyz = 世界位置
|
||||
vec4 params; // x = 类型(0=方向,1=点)，y = 衰减半径
|
||||
};
|
||||
|
||||
layout(location = 0) in vec2 fragUV;
|
||||
layout(location = 1) in vec3 fragNormal;
|
||||
layout(location = 2) in vec3 fragWorldPos;
|
||||
layout(location = 3) in float fragViewDepth;
|
||||
layout(location = 4) in vec2 fragVelocity;
|
||||
layout(location = 5) in vec3 fragTangent;
|
||||
|
||||
layout(location = 0) out vec4 outColor;
|
||||
layout(location = 1) out vec2 outVelocity; // TAA velocity 附件
|
||||
|
||||
layout(set = 0, binding = 0) uniform UniformBufferObject {
|
||||
mat4 view;
|
||||
mat4 proj;
|
||||
mat4 lightSpace[3]; // CSM 各级联光空间 VP
|
||||
vec4 cascadeSplits; // xyz = 级联 0..2 远边界（视图深度）
|
||||
vec4 ambientColor;
|
||||
Light lights[MAX_LIGHTS];
|
||||
mat4 projNoJitter;
|
||||
mat4 prevView;
|
||||
mat4 prevProj;
|
||||
vec4 cameraPos;
|
||||
} ubo;
|
||||
|
||||
// 材质纹理槽（binding = Material::Slot）
|
||||
layout(set = 1, binding = 0) uniform sampler2D albedoMap;
|
||||
layout(set = 1, binding = 1) uniform sampler2D normalMap;
|
||||
layout(set = 1, binding = 2) uniform sampler2D metallicRoughnessMap; // G=粗糙度 B=金属度
|
||||
layout(set = 1, binding = 3) uniform sampler2D emissiveMap;
|
||||
layout(set = 1, binding = 4) uniform sampler2D aoMap; // 环境光遮蔽（R 通道）
|
||||
layout(set = 1, binding = 5) uniform sampler2D roughnessMap; // 独立粗糙度图（R 通道，specular 工作流）
|
||||
layout(set = 1, binding = 6) uniform MaterialParams {
|
||||
vec4 factors; // x = metallic 因子，y = roughness 因子，z = 独立粗糙度图开关
|
||||
} matParams;
|
||||
|
||||
// CSM 阴影（sampler2DShadow：单次采样 = 硬件 2×2 深度比较 PCF）
|
||||
layout(set = 2, binding = 0) uniform sampler2DShadow shadowMap0; // CSM 级联 0（最近）
|
||||
layout(set = 2, binding = 1) uniform sampler2DShadow shadowMap1; // 级联 1
|
||||
layout(set = 2, binding = 2) uniform sampler2DShadow shadowMap2; // 级联 2（最远）
|
||||
layout(set = 2, binding = 3) uniform samplerCube irradianceMap; // 漫反射环境光（IBL 阶段②）
|
||||
layout(set = 2, binding = 4) uniform samplerCube prefilteredMap; // 镜面环境（mip 分 roughness，阶段③）
|
||||
layout(set = 2, binding = 5) uniform sampler2D brdfLut; // BRDF 积分表 (NdotV, roughness) → (scale, bias)
|
||||
|
||||
// 第 0 盏方向光（KeyLight）的 CSM 阴影因子。
|
||||
// 级联按视图深度选择；3×3 纹素偏移采样（每 tap 硬件 2×2 PCF，
|
||||
// 等效 36 次比较）→ 软阴影边缘；采样器 clamp-to-border 白色：
|
||||
// 光视锥外自动 1.0（无阴影），省出界分支
|
||||
float ShadowFactor(vec3 N, float viewDepth) {
|
||||
// 阴影总开关（ubo.cascadeSplits.w 由 CPU 每帧写入）：关闭即全亮，
|
||||
// 配合 ShadowPass 空转（深度图无内容也读不到这里）
|
||||
if (ubo.cascadeSplits.w < 0.5) return 1.0;
|
||||
|
||||
int cascade = 2;
|
||||
for (int i = 0; i < 3; ++i) {
|
||||
if (viewDepth < ubo.cascadeSplits[i]) { cascade = i; break; }
|
||||
}
|
||||
|
||||
vec4 ls = ubo.lightSpace[cascade] * vec4(fragWorldPos, 1.0);
|
||||
vec3 proj = ls.xyz / ls.w;
|
||||
vec2 uv = proj.xy * 0.5 + 0.5;
|
||||
|
||||
vec3 L = normalize(-ubo.lights[0].direction.xyz);
|
||||
float bias = max(0.004 * (1.0 - dot(N, L)), 0.0012);
|
||||
|
||||
float texel = 1.0 / float(kCascadeRes); // 与引擎 kCascadeRes 同步
|
||||
float shadow = 0.0;
|
||||
for (int y = -1; y <= 1; ++y) {
|
||||
for (int x = -1; x <= 1; ++x) {
|
||||
float lit;
|
||||
if (cascade == 0)
|
||||
lit = texture(shadowMap0, vec3(uv + vec2(x, y) * texel,
|
||||
proj.z - bias));
|
||||
else if (cascade == 1)
|
||||
lit = texture(shadowMap1, vec3(uv + vec2(x, y) * texel,
|
||||
proj.z - bias));
|
||||
else
|
||||
lit = texture(shadowMap2, vec3(uv + vec2(x, y) * texel,
|
||||
proj.z - bias));
|
||||
shadow += mix(0.3, 1.0, lit); // 影中保留 0.3 环境感
|
||||
}
|
||||
}
|
||||
return shadow / 9.0;
|
||||
}
|
||||
|
||||
// 法线贴图 → 世界空间法线（TBN 构建）。
|
||||
// 无切线数据（零向量）或平法线贴图时退回几何法线。
|
||||
vec3 MappedNormal(vec3 geomN, vec3 T, vec2 uv) {
|
||||
if (dot(T, T) < 1e-4) return geomN;
|
||||
|
||||
vec3 N = geomN;
|
||||
vec3 nT = normalize(T - N * dot(N, T)); // 正交化
|
||||
vec3 B = cross(N, nT);
|
||||
vec3 sampled = texture(normalMap, uv).xyz * 2.0 - 1.0;
|
||||
if (dot(sampled, sampled) < 1e-4) return geomN;
|
||||
|
||||
return normalize(nT * sampled.x + B * sampled.y + N * sampled.z);
|
||||
}
|
||||
|
||||
// ---- Cook-Torrance BRDF 各项 ----
|
||||
float DistributionGGX(float NdotH, float roughness) {
|
||||
float a = roughness * roughness;
|
||||
float a2 = a * a;
|
||||
float d = NdotH * NdotH * (a2 - 1.0) + 1.0;
|
||||
return a2 / (PI * d * d);
|
||||
}
|
||||
|
||||
float GeometrySmith(float NdotV, float NdotL, float roughness) {
|
||||
float r = roughness + 1.0;
|
||||
float k = (r * r) / 8.0; // 解析光源用此 k（IBL 才用 IBL 版本）
|
||||
float gv = NdotV / (NdotV * (1.0 - k) + k);
|
||||
float gl = NdotL / (NdotL * (1.0 - k) + k);
|
||||
return gv * gl;
|
||||
}
|
||||
|
||||
vec3 FresnelSchlick(float cosTheta, vec3 F0) {
|
||||
return F0 + (1.0 - F0) * pow(clamp(1.0 - cosTheta, 0.0, 1.0), 5.0);
|
||||
}
|
||||
|
||||
// 粗糙度感知的 Fresnel（IBL 用）：粗糙表面掠射边缘的 F 上升更平缓
|
||||
vec3 FresnelSchlickRoughness(float cosTheta, vec3 F0, float roughness) {
|
||||
vec3 Fmax = max(vec3(1.0 - roughness), F0);
|
||||
return F0 + (Fmax - F0) * pow(clamp(1.0 - cosTheta, 0.0, 1.0), 5.0);
|
||||
}
|
||||
|
||||
void main() {
|
||||
vec4 albedoTex = texture(albedoMap, fragUV);
|
||||
vec3 albedo = albedoTex.rgb;
|
||||
vec4 mr = texture(metallicRoughnessMap, fragUV);
|
||||
// 粗糙度源按 factors.z 切换：glTF 合图工作流读 MR.g；
|
||||
// FBX/OBJ specular 工作流（z=1）换用独立粗糙度图 R 通道
|
||||
float roughness = clamp(mix(mr.g, texture(roughnessMap, fragUV).r,
|
||||
matParams.factors.z) * matParams.factors.y,
|
||||
0.045, 1.0);
|
||||
float metallic = clamp(mr.b * matParams.factors.x, 0.0, 1.0);
|
||||
vec3 emissive = texture(emissiveMap, fragUV).rgb;
|
||||
|
||||
vec3 N = MappedNormal(normalize(fragNormal), fragTangent, fragUV);
|
||||
vec3 V = normalize(ubo.cameraPos.xyz - fragWorldPos);
|
||||
float NdotV = max(dot(N, V), 1e-4);
|
||||
vec3 F0 = mix(vec3(0.04), albedo, metallic); // 电介质基准反射率 4%
|
||||
|
||||
vec3 Lo = vec3(0.0);
|
||||
float shade0 = 1.0f; // 第 0 盏光的阴影因子（环境光同步衰减用）
|
||||
|
||||
for (int i = 0; i < MAX_LIGHTS; ++i) {
|
||||
// 按类型分支：方向光无衰减；点光方向指向光源 + 平方距离衰减
|
||||
vec3 L;
|
||||
float atten = 1.0;
|
||||
if (ubo.lights[i].params.x > 0.5) {
|
||||
vec3 toLight = ubo.lights[i].position.xyz - fragWorldPos;
|
||||
float d = length(toLight);
|
||||
if (d >= ubo.lights[i].params.y) continue;
|
||||
L = toLight / d;
|
||||
float a = clamp(1.0 - (d * d) /
|
||||
(ubo.lights[i].params.y * ubo.lights[i].params.y),
|
||||
0.0, 1.0);
|
||||
atten = a * a;
|
||||
} else {
|
||||
L = normalize(-ubo.lights[i].direction.xyz);
|
||||
}
|
||||
|
||||
vec3 radiance = ubo.lights[i].color.rgb * ubo.lights[i].color.a * atten;
|
||||
float NdotL = max(dot(N, L), 0.0);
|
||||
if (NdotL <= 0.0) continue;
|
||||
|
||||
// Cook-Torrance 镜面项
|
||||
vec3 H = normalize(V + L);
|
||||
float NdotH = max(dot(N, H), 0.0);
|
||||
float NdotH2 = max(dot(H, V), 0.0);
|
||||
float D = DistributionGGX(NdotH, roughness);
|
||||
float G = GeometrySmith(NdotV, NdotL, roughness);
|
||||
vec3 F = FresnelSchlick(NdotH2, F0);
|
||||
|
||||
vec3 kS = F;
|
||||
vec3 kD = (1.0 - kS) * (1.0 - metallic); // 金属不参与漫反射
|
||||
vec3 specular = (D * G * F) /
|
||||
max(4.0 * NdotV * NdotL, 1e-4);
|
||||
|
||||
// 阴影只来自第 0 盏方向光（CSM）
|
||||
float shade = (i == 0 && ubo.lights[0].params.x < 0.5)
|
||||
? ShadowFactor(N, fragViewDepth) : 1.0;
|
||||
if (i == 0) shade0 = shade;
|
||||
|
||||
// 漫反射影中保留 0.3（间接光近似）；镜面项是"光源的镜面像"，
|
||||
// 光源被遮挡即完全消失——按 shade 重映射（0.3→0，1.0→1）。
|
||||
// 否则掠射角下 spec(HDR 8)×0.3 仍是白块，影子比天空还亮
|
||||
float shadeSpec = max((shade - 0.3f) / 0.7f, 0.0f);
|
||||
Lo += (kD * albedo / PI) * radiance * NdotL * shade
|
||||
+ specular * radiance * NdotL * shadeSpec;
|
||||
}
|
||||
|
||||
// 环境光：IBL split-sum（阶段②③）。
|
||||
// 漫反射：N 采样 irradiance cube（半球 Lambert 预卷积）
|
||||
// 镜面：R 采样 pre-filtered cube（mip = roughness 分级）
|
||||
// × BRDF LUT 查表得 F 缩放/偏置
|
||||
// ambientColor = 用户可调强度/色调乘子
|
||||
vec3 F_amb = FresnelSchlickRoughness(NdotV, F0, roughness);
|
||||
vec3 kD_amb = (1.0 - F_amb) * (1.0 - metallic);
|
||||
|
||||
vec3 irradiance = texture(irradianceMap, N).rgb;
|
||||
float ao = texture(aoMap, fragUV).r;
|
||||
vec3 diffuse = kD_amb * irradiance * albedo * ao;
|
||||
|
||||
vec3 R = reflect(-V, N);
|
||||
const float kMaxPrefilterMip = 4.0; // 与 Cubemap::kPrefilterMips - 1 同步
|
||||
vec3 prefilteredColor = textureLod(prefilteredMap, R,
|
||||
roughness * kMaxPrefilterMip).rgb;
|
||||
vec2 envBRDF = texture(brdfLut, vec2(NdotV, roughness)).rg;
|
||||
vec3 specular = prefilteredColor * (F_amb * envBRDF.x + envBRDF.y);
|
||||
|
||||
vec3 ambient = (diffuse + specular) * ubo.ambientColor.rgb
|
||||
* mix(0.4, 1.0, shade0); // 阴影区环境同步衰减（简化遮蔽）
|
||||
|
||||
// alpha = albedo 贴图覆盖率（glTF alphaMode=BLEND 混合源）；
|
||||
// 不透明资产贴图 a=1 行为不变。预乘在 tonemap 段完成。
|
||||
outColor = vec4(ambient + Lo + emissive, albedoTex.a);
|
||||
outVelocity = fragVelocity;
|
||||
|
||||
// 深度语义：真实深度测试 + 真实写入（depthWrite 状态保持 TRUE——
|
||||
// 绕开 NVIDIA shader-object "depthWrite=FALSE 下绘制" 的灾难病态）。
|
||||
// 早期版本在此写 gl_FragDepth=1.0 模拟"只测不写"，但深度比较符是
|
||||
// eLess：片元自身的 1.0 对清屏值 1.0 与不透明深度（更小）永远测试
|
||||
// 失败，透明队列一个像素都出不来（Transparent 调试视图实锤）。
|
||||
// 透明段是帧内最后一个 pass 且深度每帧清空，真实写入无副作用；
|
||||
// back-to-front 排序下近面后画恒通过，混合顺序仍由排序保证。
|
||||
}
|
||||
@@ -1,6 +1,7 @@
|
||||
#version 450
|
||||
|
||||
// Tonemap pass：HDR（+bloom）→ 显示空间，兼调试视图路由上屏。
|
||||
// Tonemap pass：HDR（+bloom）→ 显示空间，写 PresentTarget（offscreen，
|
||||
// 由 ImGui::Image 呈现；输出位置可自由摆放）。
|
||||
// 这是显示变换的显式建模（对齐 UE/Unity：HDR SceneColor → tonemapper → UI）。
|
||||
// ACES = Narkowicz 拟合（线性域映射到 [0,1]），可经 push constant 关闭
|
||||
// 退回纯 gamma（旧观感）。
|
||||
@@ -40,6 +41,7 @@ const int VIEW_ENV_CUBE = 9;
|
||||
const int VIEW_IRRADIANCE = 10;
|
||||
const int VIEW_PREFILTER = 11;
|
||||
const int VIEW_BRDF_LUT = 12;
|
||||
const int VIEW_TRANSPARENT = 13;
|
||||
|
||||
// 全屏 pass 通用 push（16B，程序级统一声明，VUID-08878）
|
||||
layout(push_constant) uniform PushConstants {
|
||||
@@ -90,7 +92,11 @@ void main() {
|
||||
outColor = vec4(pow(d, vec3(1.0 / 2.2)), 1.0);
|
||||
return;
|
||||
}
|
||||
case VIEW_RAW_HDR: outColor = vec4(tonemap(texture(rawHdrImage, fragUV).rgb), 1.0); return;
|
||||
// Transparent 视图：场景侧已跳过天空盒/不透明绘制，
|
||||
// raw HDR = 清屏色 + 透明队列内容（与 RAW_HDR 同一显示路径）
|
||||
case VIEW_RAW_HDR:
|
||||
case VIEW_TRANSPARENT:
|
||||
outColor = vec4(tonemap(texture(rawHdrImage, fragUV).rgb), 1.0); return;
|
||||
case VIEW_TAA: outColor = vec4(tonemap(texture(taaImage, fragUV).rgb), 1.0); return;
|
||||
case VIEW_BLOOM: outColor = vec4(tonemap(texture(bloomImage, fragUV).rgb * 4.0), 1.0); return;
|
||||
case VIEW_VELOCITY: {
|
||||
|
||||
Reference in New Issue
Block a user