#version 450

const int MAX_LIGHTS = 4;

struct Light {
    vec4 direction;
    vec4 color;
};

layout(location = 0) in vec2 fragUV;
layout(location = 1) in vec3 fragNormal;
layout(location = 2) in vec3 fragWorldPos;
layout(location = 3) in vec3 fragLightSpacePos;

layout(location = 0) out vec4 outColor;

layout(set = 0, binding = 0) uniform UniformBufferObject {
    mat4 view;
    mat4 proj;
    mat4 lightSpace;
    vec4 ambientColor;
    Light lights[MAX_LIGHTS];
} ubo;

layout(set = 1, binding = 0) uniform sampler2D texSampler;
layout(set = 2, binding = 0) uniform sampler2D shadowMap;

// 第 0 盏灯（KeyLight）的阴影因子：0.3 影中 / 1.0 受光。
// 采样器为 clamp-to-border 白色：光视锥外自动 1.0（无阴影）。
float ShadowFactor(vec3 N) {
    // NDC [-1,1] → UV [0,1]（ortho 的 w=1，无需透视除法）
    vec2 uv = fragLightSpacePos.xy * 0.5 + 0.5;
    float closest = texture(shadowMap, uv).r;

    // 斜率缩放 bias：掠射面用更大的 bias 压 acne
    vec3 L = normalize(-ubo.lights[0].direction.xyz);
    float bias = max(0.004 * (1.0 - dot(N, L)), 0.0012);

    return (fragLightSpacePos.z - bias > closest) ? 0.3 : 1.0;
}

void main() {
    vec3 albedo = texture(texSampler, fragUV).rgb;
    vec3 N = normalize(fragNormal);

    vec3 result = ubo.ambientColor.rgb * albedo;

    for (int i = 0; i < MAX_LIGHTS; ++i) {
        vec3 L = normalize(-ubo.lights[i].direction.xyz);
        float diff = max(dot(N, L), 0.0);
        float shade = (i == 0) ? ShadowFactor(N) : 1.0;
        result += ubo.lights[i].color.rgb * ubo.lights[i].color.a * diff * albedo * shade;
    }

    outColor = vec4(result, 1.0);
}